OSDev

для всех
Текущее время: 12 дек 2017, 11:11

Часовой пояс: UTC + 3 часа




Начать новую тему Ответить на тему  [ Сообщений: 7 ] 
Автор Сообщение
СообщениеДобавлено: 06 фев 2016, 02:45 

Зарегистрирован: 15 сен 2015, 14:42
Сообщения: 5
Приветствую!

Работаю с vbe, уже научился использовать банки, LFB и буфер - рисую картинки в svga режиме. Все замечательно, но только ядро работает в qemu эмуляторе и не работает в Bochs, VirtualBox, VMware. Вылетает GPF с кодом ошибки = 0.

Вся проблема с функцией int32 - Protected Mode BIOS Call Functionailty v2.0 - by Napalm. Ее я выбрал как самую простую.

Еще симптом: если отключить переключение в страничный режим адресации, то работает во всех эмуляторах.

Код:
// чтение VBE
regs.ax = 0x4f00;
int32(0x10, &regs); // <-- вот здесь все крашится



В какую сторону копать?

Исходник или http://www.rohitab.com/discuss/topic/35103-switch-between-real-mode-and-protected-mode/
Код:
;
; Protected Mode BIOS Call Functionailty v2.0 - by Napalm
; -------------------------------------------------------
;
; This is code shows how its POSSIBLE to execute BIOS interrupts
; by switch out to real-mode and then back into protected mode.
;
; If you wish to use all or part of this code you must agree
; to the license at the following URL.
;
; License: http://creativecommons.org/licenses/by-sa/2.0/uk/
;         
; Notes: This file is in NASM syntax.
;        Turn off paging before calling these functions.
;        int32() resets all selectors.
;
; C Prototype:
;   void _cdelc int32(unsigned char intnum, regs16_t *regs);
;
; Example of usage:
;   regs.ax = 0x0013;
;   int32(0x10, &regs);
;   memset((char *)0xA0000, 1, (320*200));
;   memset((char *)0xA0000 + (100*320+80), 14, 80);
;   regs.ax = 0x0000;
;   int32(0x16, &regs);
;   regs.ax = 0x0003;
;   int32(0x10, &regs);
;
;
[bits 32]

global int32, _int32

struc regs16_t
   .di   resw 1
   .si   resw 1
   .bp   resw 1
   .sp resw 1
   .bx   resw 1
   .dx   resw 1
   .cx   resw 1
   .ax   resw 1
   .gs   resw 1
   .fs   resw 1
   .es   resw 1
   .ds   resw 1
   .ef resw 1
endstruc

%define INT32_BASE                             0x7C00
%define REBASE(x)                              (((x) - reloc) + INT32_BASE)
%define GDTENTRY(x)                            ((x) << 3)
%define CODE32                                 GDTENTRY(1)   ; 0x08
%define DATA32                                 GDTENTRY(2)   ; 0x10
%define CODE16                                 GDTENTRY(3)   ; 0x18
%define DATA16                                 GDTENTRY(4)   ; 0x20
%define STACK16                                (INT32_BASE - regs16_t_size)


section .text
   int32: use32                               ; by Napalm
   _int32:
      cli                                    ; disable interrupts
      pusha                                  ; save register state to 32bit stack
      mov  esi, reloc                        ; set source to code below
      mov  edi, INT32_BASE                   ; set destination to new base address
      mov  ecx, (int32_end - reloc)          ; set copy size to our codes size
      cld                                    ; clear direction flag (so we copy forward)
      rep  movsb                             ; do the actual copy (relocate code to low 16bit space)
      jmp INT32_BASE                         ; jump to new code location
   reloc: use32                               ; by Napalm
      mov  [REBASE(stack32_ptr)], esp        ; save 32bit stack pointer
      sidt [REBASE(idt32_ptr)]               ; save 32bit idt pointer
      sgdt [REBASE(gdt32_ptr)]               ; save 32bit gdt pointer
      lgdt [REBASE(gdt16_ptr)]               ; load 16bit gdt pointer
      lea  esi, [esp+0x24]                   ; set position of intnum on 32bit stack
      lodsd                                  ; read intnum into eax
      mov  [REBASE(ib)], al                  ; set intrrupt immediate byte from our arguments
      mov  esi, [esi]                        ; read regs pointer in esi as source
      mov  edi, STACK16                      ; set destination to 16bit stack
      mov  ecx, regs16_t_size                ; set copy size to our struct size
      mov  esp, edi                          ; save destination to as 16bit stack offset
      rep  movsb                             ; do the actual copy (32bit stack to 16bit stack)
      jmp  word CODE16:REBASE(p_mode16)      ; switch to 16bit selector (16bit protected mode)
   p_mode16: use16
      mov  ax, DATA16                        ; get our 16bit data selector
      mov  ds, ax                            ; set ds to 16bit selector
      mov  es, ax                            ; set es to 16bit selector
      mov  fs, ax                            ; set fs to 16bit selector
      mov  gs, ax                            ; set gs to 16bit selector
      mov  ss, ax                            ; set ss to 16bit selector
      mov  eax, cr0                          ; get cr0 so we can modify it
      and  al,  ~0x01                        ; mask off PE bit to turn off protected mode
      mov  cr0, eax                          ; set cr0 to result
      jmp  word 0x0000:REBASE(r_mode16)      ; finally set cs:ip to enter real-mode
   r_mode16: use16
      xor  ax, ax                            ; set ax to zero
      mov  ds, ax                            ; set ds so we can access idt16
      mov  ss, ax                            ; set ss so they the stack is valid
      lidt [REBASE(idt16_ptr)]               ; load 16bit idt
      mov  bx, 0x0870                        ; master 8 and slave 112
      call resetpic                          ; set pic's the to real-mode settings
      popa                                   ; load general purpose registers from 16bit stack
      pop  gs                                ; load gs from 16bit stack
      pop  fs                                ; load fs from 16bit stack
      pop  es                                ; load es from 16bit stack
      pop  ds                                ; load ds from 16bit stack
      sti                                    ; enable interrupts
      db 0xCD                                ; opcode of INT instruction with immediate byte
   ib: db 0x00
      cli                                    ; disable interrupts
      xor  sp, sp                            ; zero sp so we can reuse it
      mov  ss, sp                            ; set ss so the stack is valid
      mov  sp, INT32_BASE                    ; set correct stack position so we can copy back
      pushf                                  ; save eflags to 16bit stack
      push ds                                ; save ds to 16bit stack
      push es                                ; save es to 16bit stack
      push fs                                ; save fs to 16bit stack
      push gs                                ; save gs to 16bit stack
      pusha                                  ; save general purpose registers to 16bit stack
      mov  bx, 0x2028                        ; master 32 and slave 40
      call resetpic                          ; restore the pic's to protected mode settings
      mov  eax, cr0                          ; get cr0 so we can modify it
      inc  eax                               ; set PE bit to turn on protected mode
      mov  cr0, eax                          ; set cr0 to result
      jmp  dword CODE32:REBASE(p_mode32)     ; switch to 32bit selector (32bit protected mode)
   p_mode32: use32
      mov  ax, DATA32                        ; get our 32bit data selector
      mov  ds, ax                            ; reset ds selector
      mov  es, ax                            ; reset es selector
      mov  fs, ax                            ; reset fs selector
      mov  gs, ax                            ; reset gs selector
      mov  ss, ax                            ; reset ss selector
      lgdt [REBASE(gdt32_ptr)]               ; restore 32bit gdt pointer
      lidt [REBASE(idt32_ptr)]               ; restore 32bit idt pointer
      mov  esp, [REBASE(stack32_ptr)]        ; restore 32bit stack pointer
      mov  esi, STACK16                      ; set copy source to 16bit stack
      lea  edi, [esp+0x28]                   ; set position of regs pointer on 32bit stack
      mov  edi, [edi]                        ; use regs pointer in edi as copy destination
      mov  ecx, regs16_t_size                ; set copy size to our struct size
      cld                                    ; clear direction flag (so we copy forward)
      rep  movsb                             ; do the actual copy (16bit stack to 32bit stack)
      popa                                   ; restore registers
      sti                                    ; enable interrupts
      ret                                    ; return to caller
      
   resetpic:                                  ; reset's 8259 master and slave pic vectors
      push ax                                ; expects bh = master vector, bl = slave vector
      mov  al, 0x11                          ; 0x11 = ICW1_INIT | ICW1_ICW4
      out  0x20, al                          ; send ICW1 to master pic
      out  0xA0, al                          ; send ICW1 to slave pic
      mov  al, bh                            ; get master pic vector param
      out  0x21, al                          ; send ICW2 aka vector to master pic
      mov  al, bl                            ; get slave pic vector param
      out  0xA1, al                          ; send ICW2 aka vector to slave pic
      mov  al, 0x04                          ; 0x04 = set slave to IRQ2
      out  0x21, al                          ; send ICW3 to master pic
      shr  al, 1                             ; 0x02 = tell slave its on IRQ2 of master
      out  0xA1, al                          ; send ICW3 to slave pic
      shr  al, 1                             ; 0x01 = ICW4_8086
      out  0x21, al                          ; send ICW4 to master pic
      out  0xA1, al                          ; send ICW4 to slave pic
      pop  ax                                ; restore ax from stack
      ret                                    ; return to caller
      
   stack32_ptr:                               ; address in 32bit stack after we
      dd 0x00000000                          ;   save all general purpose registers
      
   idt32_ptr:                                 ; IDT table pointer for 32bit access
      dw 0x0000                              ; table limit (size)
      dd 0x00000000                          ; table base address
      
   gdt32_ptr:                                 ; GDT table pointer for 32bit access
      dw 0x0000                              ; table limit (size)
      dd 0x00000000                          ; table base address
      
   idt16_ptr:                                 ; IDT table pointer for 16bit access
      dw 0x03FF                              ; table limit (size)
      dd 0x00000000                          ; table base address
      
   gdt16_base:                                ; GDT descriptor table
      .null:                                 ; 0x00 - null segment descriptor
         dd 0x00000000                      ; must be left zero'd
         dd 0x00000000                      ; must be left zero'd
         
      .code32:                               ; 0x01 - 32bit code segment descriptor 0xFFFFFFFF
         dw 0xFFFF                          ; limit  0:15
         dw 0x0000                          ; base   0:15
         db 0x00                            ; base  16:23
         db 0x9A                            ; present, iopl/0, code, execute/read
         db 0xCF                            ; 4Kbyte granularity, 32bit selector; limit 16:19
         db 0x00                            ; base  24:31
         
      .data32:                               ; 0x02 - 32bit data segment descriptor 0xFFFFFFFF
         dw 0xFFFF                          ; limit  0:15
         dw 0x0000                          ; base   0:15
         db 0x00                            ; base  16:23
         db 0x92                            ; present, iopl/0, data, read/write
         db 0xCF                            ; 4Kbyte granularity, 32bit selector; limit 16:19
         db 0x00                            ; base  24:31
         
      .code16:                               ; 0x03 - 16bit code segment descriptor 0x000FFFFF
         dw 0xFFFF                          ; limit  0:15
         dw 0x0000                          ; base   0:15
         db 0x00                            ; base  16:23
         db 0x9A                            ; present, iopl/0, code, execute/read
         db 0x0F                            ; 1Byte granularity, 16bit selector; limit 16:19
         db 0x00                            ; base  24:31
         
      .data16:                               ; 0x04 - 16bit data segment descriptor 0x000FFFFF
         dw 0xFFFF                          ; limit  0:15
         dw 0x0000                          ; base   0:15
         db 0x00                            ; base  16:23
         db 0x92                            ; present, iopl/0, data, read/write
         db 0x0F                            ; 1Byte granularity, 16bit selector; limit 16:19
         db 0x00                            ; base  24:31
         
   gdt16_ptr:                                 ; GDT table pointer for 16bit access
      dw gdt16_ptr - gdt16_base - 1          ; table limit (size)
      dd gdt16_base                          ; table base address
      
   int32_end:                                 ; end marker (so we can copy the code)
   
   


Вернуться к началу
 Профиль  
 
СообщениеДобавлено: 06 фев 2016, 03:02 

Зарегистрирован: 26 мар 2012, 17:32
Сообщения: 208
Ясно же написано:
Цитата:
; Notes:
; Turn off paging before calling these functions
Т.е. всё происходит "согласно купленным билетам".
А так, переключаться в реальный режим и обратно - извращение же дикое. Есть V86 (со своими ограничениями), есть библиотеки для программной эмуляции (нет тут нужды в большой скорости чтобы один раз позвать переключение видеорежима).


Вернуться к началу
 Профиль  
 
СообщениеДобавлено: 07 фев 2016, 00:36 

Зарегистрирован: 10 окт 2013, 14:54
Сообщения: 80
Nable писал(а):
А так, переключаться в реальный режим и обратно - извращение же дикое.
Да ладно - а как все DOS4G и прочие экстендеры под DOSом жили?
Вполне себе игрушки бегали - на процах типа 486...

Хотя банки, на самом деле, нафиг не нужны уже тыщу лет, а возни с ними - мама дорогая...
Там в общем случае дофига граблей, типа WinA тока под чтение, а WinB тока под запись и такие карты реально были.
Собстно, щас тока древние компы с VESA 1.x картами и VirtualPC 2007 требуют работы с банками ;)


Вернуться к началу
 Профиль  
 
СообщениеДобавлено: 07 фев 2016, 00:55 

Зарегистрирован: 26 мар 2012, 17:32
Сообщения: 208
dixie писал(а):
Да ладно - а как все DOS4G и прочие экстендеры под DOSом жили?
Вполне себе игрушки бегали - на процах типа 486...
В жизни вообще много костылей, подпорок и извращений, возникающих по разным причинам. Иногда они имеют смысл потому что хочется результат "здесь и сейчас, а потом хоть трава не расти" и это действительно временное решение, но если есть возможность сделать одним извращением меньше - лучше сразу делать так.

dixie писал(а):
Хотя банки, на самом деле, нафиг не нужны уже тыщу лет, а возни с ними - мама дорогая...
Там в общем случае дофига граблей, типа WinA тока под чтение, а WinB тока под запись и такие карты реально были.
Собстно, щас тока древние компы с VESA 1.x картами и VirtualPC 2007 требуют работы с банками ;)
А причём тут банки? Ну т.е. они тоже упомянуты, но это далеко не единственное (и не главное), ради чего приходится дёргать функции VBIOS. Насколько помню, эти функции сильно нужны чтобы получить адрес LFB и получить/установить видеорежим в условиях когда в ОС ещё нет родного (native) драйвера для той или иной видеокарточки.


Вернуться к началу
 Профиль  
 
СообщениеДобавлено: 07 фев 2016, 15:14 

Зарегистрирован: 10 окт 2013, 14:54
Сообщения: 80
Nable писал(а):
А причём тут банки? Ну т.е. они тоже упомянуты, но это далеко не единственное (и не главное), ради чего приходится дёргать функции VBIOS.
Естественно, просто с ними можно не мучаться, в общем-то ;)

А насчёт "извращений" и прерываний - ходить в реальный можно по многим причинам и довольно долго. И всё это работает - кривизна результата зависит больше от реализации, а никак не от идеологических причин "нелюбви к костылям" ;)


Вернуться к началу
 Профиль  
 
СообщениеДобавлено: 07 фев 2016, 16:08 

Зарегистрирован: 28 окт 2007, 18:33
Сообщения: 1315
Откуда: Зеленоград
Если на то пошло, на ПК в принципе невозможно обойтись без костылей в силу костыльной архитектуры самой аппаратуры. Так что надо не пытаться придумать, как без них обойтись (ибо невозможно), а думать, как сделать это дело наиболее прямым образом. Ну и, естественно, все эти костыли должны использоваться только там, где без них обойтись нельзя (загрузка и инициализация ОС, а также, возможно, драйвер видео), а основная часть системы должна быть совершенно "прямой".


Вернуться к началу
 Профиль  
 
СообщениеДобавлено: 19 мар 2016, 21:18 

Зарегистрирован: 21 сен 2007, 17:24
Сообщения: 1025
Откуда: Балаково
Nable писал(а):
А так, переключаться в реальный режим и обратно - извращение же дикое. Есть V86 (со своими ограничениями), есть библиотеки для программной эмуляции (нет тут нужды в большой скорости чтобы один раз позвать переключение видеорежима).

Дикое или не дикое, но работает исправно. А вот V86 бесполезен, потому что BIOS подразумевает настоящий реальный режим, используя коды с переходом в 32-битный режим, а порой и в SMM, поэтому в V86 почти ничего не работает. И тем более, что в 64-битном режиме уже нет поддержки V86 - требуется переключение в 32-битный режим.


Вернуться к началу
 Профиль  
 
Показать сообщения за:  Поле сортировки  
Начать новую тему Ответить на тему  [ Сообщений: 7 ] 

Часовой пояс: UTC + 3 часа


Кто сейчас на конференции

Сейчас этот форум просматривают: нет зарегистрированных пользователей и гости: 1


Вы не можете начинать темы
Вы не можете отвечать на сообщения
Вы не можете редактировать свои сообщения
Вы не можете удалять свои сообщения
Вы не можете добавлять вложения

Найти:
Перейти:  
cron
Создано на основе phpBB® Forum Software © phpBB Group
Русская поддержка phpBB